Windows系统切换设置IP地址脚本

主界面预览脚本功能脚本内容

修改默认网卡
使用’选择网卡’查看本机所有网卡修改脚本中的"以太网"为默认网卡

set Nic=以太网

设置为dhcp自动获取IP地址设置为手动IP地址
分别提示ip地址、子网掩码、网关、dns,根据输入设置
脚本内置两种方案
根据脚本中定义好的IP地址一键设置可分别定义网卡、IP、掩码、网关、主DNS、辅DNS.一键设置

将以下内容保存为bat文件即可使用

   @echo off
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
cls
echo.
color 0a

rem //设置默认网卡
set Nic=以太网
:MENU
cls
echo  当前网卡为"%Nic%"
echo   1－选择网卡
echo   2－自动获取IP
echo   3－手动输入静态IP
echo   4－使用脚本中定义的静态IP
echo   5－退出脚本
Set /p input=请输入您的选择:

if %input% == 1 goto selectNic
if %input% == 2 goto dhcp
if %input% == 3 goto static
if %input% == 4 goto script
if %input% == 5 goto exit
goto :MENU

:selectNic
cmd /c netsh interface ipv4 show interface
Set /p Nic=请输入您的选择:
goto MENU

:dhcp
netsh interface ip set address name=%Nic% source=dhcp
netsh interface ip delete dns %Nic% all  >nul
goto MENU

:static
Set /p ip=请输入IP地址(如192.168.1.2):
Set /p mask=请输入子网掩码(如255.255.255.0):
Set /p gateway=请输入网关(如192.168.1.1):
Set /p dns1=请输入主DNS(如223.5.5.5):
Set /p dns2=请输入辅DNS(如223.6.6.6):
goto setip

:script
Set ip=192.168.85.10
Set mask=255.255.255.0
Set gateway=192.168.85.1
Set dns1=192.168.85.1
Set dns2=223.5.5.5
goto setip

:setip
echo 本程序将修改IP地址
echo 网卡:%Nic%
echo IP地址:%ip%
echo 子网掩码:%mask%
echo 网关:%gateway%
echo 主DNS:%dns1%
echo 辅DNS:%dns2%
echo 按任意键开始设置(需要管理员权限)
pause >nul
Echo *******************************************************************************
Echo           正在修改IP地址和DNS服务器地址,请耐心等待…………
Echo *******************************************************************************
cmd /c netsh interface ip set address name=%Nic% source=static addr=%ip% mask=%mask% gateway=%gateway% gwmetric=1
cmd /c netsh interface ip set dns name=%Nic% source=static addr=%dns1% >nul
cmd /c netsh interface ip add dns name=%Nic% addr=%dns2% index=2 >nul
echo 设置完成
Pause
goto MENU
:exit
echo 退出脚本
goto :eof